How to Convert Hours to Minutes in Excel (and Back Again)

Minutes are often the easiest unit to work with: they are whole numbers, they need no special format, and they convert cleanly into pay or billing increments. The formula you need depends on what is in the cell. If it holds a decimal number like 7.5, multiply by 60. If it holds a time value like 7:30, multiply by 1,440. Mixing these up is the most common source of wrong answers. For a quick single conversion, the hours to minutes converter gives the answer directly.

Check which kind of hours you have

Select the cell and change its format to General (Ctrl+1, or Cmd+1 on a Mac, then General). If 7:30 turns into 0.3125, it is a time value, Excel’s fraction of a day. If it stays 7.5, it is a decimal number of hours. Press Ctrl+Z (Cmd+Z) to undo the format change afterward.

Convert decimal hours to minutes

For decimal hours, multiply by 60:

=A2*60
=CONVERT(A2,"hr","mn")

Both formulas return the same results. In CONVERT, “mn” is the unit code for minutes; recent versions of Excel also accept “min”, but “mn” works in every version. Note that 8.33 hours is not a whole number of minutes. Wrap the formula as =ROUND(A2*60,0) if you need 500.

Convert time values to minutes

For a time or duration like 7:45, multiply by 1,440, the number of minutes in a day (24 × 60):

=A2*1440
=HOUR(A2)*60+MINUTE(A2)

Format the results as General. If Excel copies the time format into column B, 465 minutes appears as 0:00, because the cell is reading it as 465 whole days.

The last row shows why =A2*1440 is the better default. HOUR returns only the hour of the day, so a 41:30 total loses its whole day and comes out as 1,050 minutes instead of 2,490. Use the HOUR and MINUTE version only for single entries under 24 hours. =CONVERT(A2,"day","mn") is another equivalent of multiplying by 1,440.

Time arithmetic also carries floating-point noise. A shift from 8:00 AM to 3:20 PM, calculated as a difference times 1,440, can come out as 439.99999999999994. It displays as 440, but INT would return 439 and an exact comparison with 440 would fail. When you need whole minutes, round:

=ROUND(A2*1440,0)

Show a time as total minutes with [mm]

Sometimes you don’t need a new column, just a different view. Select the cells, press Ctrl+1 (Cmd+1), choose Custom and type [mm]. A duration of 7:45 now displays as 465, and 1:02:30 formatted as [mm]:ss displays as 62:30. The brackets mean elapsed minutes and are required: on its own, mm is read as a month.

Two caveats. First, this changes only the display. The value is still 0.322917 of a day, so multiplying the cell by a per-minute rate gives the wrong answer. Second, seconds are hidden rather than rounded. Google Sheets offers elapsed minutes too, under Format → Number → Custom date and time; if you just need the number, =A2*1440 works identically in both programs.

Convert minutes back to hours

Reverse the operation by dividing, and choose the output that suits the reader:

=A2/60
=A2/1440
=INT(A2/60)&" h "&MOD(A2,60)&" min"

Column B is shown rounded to two decimals (50 minutes is 0.833333 hours). Column C must use the [h]:mm format, or 2,490 minutes will display as 17:30. The text formula expects whole minutes: with 499.8 it returns “8 h 19.8 min”. If your minutes have decimals, round them inside the formula:

=INT(ROUND(A2,0)/60)&" h "&MOD(ROUND(A2,0),60)&" min"

That returns “8 h 20 min” for 499.8. =CONVERT(A2,"mn","hr") is equivalent to dividing by 60, and the minutes to hours converter is handy for spot checks.

Total minutes for a timesheet

Minutes make a clean audit trail for a weekly timesheet. With clock-in times in B, clock-out times in C and unpaid break minutes in D:

=ROUND((C2-B2)*1440,0)-D2
=SUM(E2:E6)
=E7/60
=E7/1440

Fill the first formula down from E2 to E6 and put the total in E7. The week comes to 2,360 minutes, which is 39.33 decimal hours (=E7/60, rounded) or 39:20 (=E7/1440 formatted as [h]:mm). The ROUND matters on Thursday, the 8:00 AM to 3:20 PM shift from the floating-point example above. For shifts that cross midnight, replace C2-B2 with MOD(C2-B2,1). A complete layout with lunch deductions is in Excel timesheet with lunch breaks.

Hours and seconds

Seconds follow the same pattern with bigger multipliers:

=A2*3600
=A2*86400
=A2/86400

The first converts decimal hours to seconds (2.5 hours is 9,000 seconds). The second converts a time value to seconds (1:23:45 is 5,025 seconds). The third turns seconds back into a time value; format it as [h]:mm:ss. For decimal hours, =CONVERT(A2,"hr","sec") gives the same result as multiplying by 3,600.

Common errors and fixes

• 7:30 became 18.75 instead of 450. A time value was multiplied by 60. Use 1,440 for time values and 60 for decimal hours.
• The result shows 0:00 or a date. The result cell has a time or date format. Set it to General.
• A 41:30 total converts to 1,050 minutes. HOUR ignores whole days. Use =A2*1440.
• 439.99999 instead of 440. Floating-point noise from time arithmetic. Wrap the formula in ROUND(…,0).
• #VALUE!, or a total of 0. The times are text. Convert with =--A2*1440 or =TIMEVALUE(A2)*1440, or fix the whole column with Data → Text to Columns → Finish.
• [mm] shows the right number but formulas use a different one. Formatting never converts the value. Use =A2*1440 for a real minute count.
• 1.30 was meant as 1 hour 30 minutes. That is not decimal hours. Convert it with =INT(A2)*60+ROUND(MOD(A2,1)*100,0), which returns 90.

When payroll needs decimal hours rather than minutes, see convert time to decimal in Excel.